by Svetlana Cheusheva, updated on
Comparing columns in Excel is something that we all do once in a while. Microsoft Excel offers a number of options to compare and match data, but most of them focus on searching in one column. In this tutorial, we will explore several techniques to compare two columns in Excel and find matches and differences between them.
When you do data analysis in Excel, one of the most frequent tasks is comparing data in each individual row. This task can be done by using the IF function, as demonstrated in the following examples.
To compare two columns in Excel row-by-row, write a usual IF formula that compares the first two cells. Enter the formula in some other column in the same row, and then copy it down to other cells by dragging the fill handle (a small square in the bottom-right corner of the selected cell). As you do this, the cursor changes to the plus sign:
To find cells within the same row having the same content, A2 and B2 in this example, the formula is as follows:
To find cells in the same row with different values, simply replace the equals sign with the non-equality sign (<>):
And of course, nothing prevents you from finding both matches and differences with a single formula:
The result may look similar to this:
As you see, the formula handles numbers, dates, times and text strings equally well.
Tip. You can also compare two columns row-by-row using Excel Advanced Filter. Here is an example showing how to filter matches and differences between 2 columns.
As you have probably noticed, the formulas from the previous example ignore case when comparing text values, as in row 10 in the screenshot above. If you want to find case-sensitive matches between 2 columns in each row, then use the EXACT function:
=IF(EXACT(A2, B2), "Match", "")
To find case-sensitive differences in the same row, enter the corresponding text ("Unique" in this example) in the 3rd argument of the IF function, e.g.:
=IF(EXACT(A2, B2), "Match", "Unique")
In your Excel worksheets, multiple columns can be compared based on the following criteria:
If your table has three or more columns and you want to find rows that have the same values in all cells, an IF formula with an AND statement will work a treat:
=IF(AND(A2=B2, A2=C2), "Full match", "")
If your table has a lot of columns, a more elegant solution would be using the COUNTIF function:
=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")
Where 5 is the number of columns you are comparing.
If you are looking for a way to compare columns for any two or more cells with the same values within the same row, use an IF formula with an OR statement:
=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")
In case there are many columns to compare, your OR statement may grow too big in size. In this case, a better solution would be adding up several COUNTIF functions. The first COUNTIF counts how many columns have the same value as in the 1st column, the second COUNTIF counts how many of the remaining columns are equal to the 2nd column, and so on. If the count is 0, the formula returns "Unique", "Match" otherwise. For example:
Suppose you have 2 lists of data in Excel, and you want to find all values (numbers, dates or text strings) which are in column A but not in column B.
For this, you can embed the COUNTIF($B:$B, $A2)=0 function in IF's logical test and check if it returns zero (no match is found) or any other number (at least 1 match is found).
For instance, the following IF/COUNTIF formula searches across the entire column B for the value in cell A2. If no match is found, the formula returns "No match in B", an empty string otherwise:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "")
Tip. If your table has a fixed number of rows, you can specify a certain range (e.g. $B2:$B10) rather than the entire column ($B:$B) for the formula to work faster on large data sets.
The same result can be achieved by using an IF formula with the embedded ISERROR and MATCH functions:
=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)),"No match in B","")
Or, by using the following array formula (remember to press Ctrl + Shift + Enter to enter it correctly):
=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")
If you want a single formula to identify both matches (duplicates) and differences (unique values), put some text for matches in the empty double quotes ("") in any of the above formulas. For example:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "Match in B")
Sometimes you may need not only match two columns in two different tables, but also pull matching entries from the lookup table. Microsoft Excel provides a special function for this - the VLOOKUP function. As an alternative, you can use a more powerful and versatile INDEX MATCH formula. The users of Excel 2021 and Excel 365, can accomplish the task with the XLOOKUP function.
For example, the following formulas compare the product names in columns D against the names in column A and pull a corresponding sales figure from column B if a match is found, otherwise the #N/A error is returned.
=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)
=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))
=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)
For more information, please see How to compare two columns using VLOOKUP.
If you don't feel very comfortable with formulas, you can have the job done using a fast and intuitive solution - Merge Tables Wizard.
When you compare columns in Excel, you may want to "visualize" the items that are present in one column but missing in the other. You can shade such cells in any color of your choosing by using the Excel Conditional Formatting feature and the following examples demonstrate the detailed steps.
To compare two columns and Excel and highlight cells in column A that have identical entries in column B in the same row, do the following:
=$B2=$A2(assuming that row 2 is the first row with data, not including the column header). Please double check that you use a relative row reference (without the $ sign) like in the formula above.
To highlight differences between column A and B, create a rule with this formula:
If you are new to Excel conditional formatting, please see How to create a formula-based conditional formatting rule for step-by-step instructions.
Whenever you are comparing two lists in Excel, there are 3 item types that you can highlight:
This example demonstrates how to color the items that are only in one list.
Supposing your List 1 is in column A (A2:A6) and List 2 in column C (C2:C5). You create the conditional formatting rules with the following formulas:
Highlight unique values in List 1 (column A):
Highlight unique values in List 2 (column C):
And get the following result:
If you closely followed the previous example, you won't have difficulties adjusting the COUNTIF formulas so that they find the matches rather than differences. All you have to do is to set the count greater than zero:
Highlight matches in List 1 (column A):
Highlight matches in List 2 (column C):
When comparing values in several columns row-by-row, the quickest way to highlight matches is creating a conditional formatting rule, and the fastest way to shade differences is embracing the Go To Special feature, as demonstrated in the following examples.
To highlight rows that have identical values in all columns, create a conditional formatting rule based on one of the following formulas:
Where A2, B2 and C2 are the top-most cells and 3 is the number of columns to compare.
Of course, neither AND nor COUNTIF formula is limited to comparing only 3 columns, you can use similar formulas to highlight rows with the same values in 4, 5, 6 or more columns.
To quickly highlight cells with different values in each individual row, you can use Excel's Go To Special feature.
By default, the top-most cell of the selected range is the active cell, and the cells from the other selected columns in the same row will be compared to that cell. As you can see in the screenshot above, the active cell is white while all other cells of the selected range are highlighted. In this example, the active cell is A2, so the comparison column is column A.
To change the comparison column, use either the Tab key to navigate through selected cells from left to right, or the Enter key to move from top to bottom.
Tip. To select non-adjacent columns, select the first column, press and hold Ctrl, and then select the other columns. The active cell will be in the last column (or in the last block of adjacent columns). To change the comparison column, use the Tab or Enter key as described above.
In fact, comparing 2 cells is a particular case of comparing two columns in Excel row-by-row except that you don't have to copy the formulas down to other cells in the column.
For example, to compare cells A1 and C1, you can use the following formulas.
=IF(A1=C1, "Match", "")
=IF(A1<>C1, "Difference", "")
To learn a few other ways to compare cells in Excel, please see:
Now that you know Excel's offerings for comparing and matching columns, let me show you our own solution for this task. This tool is named Compare Two Tables and it is included in our Ultimate Suite.
The add-in can compare two tables or lists by any number of columns and both identify matches/differences (as we did with formulas) and highlight them (as we did with conditional formatting).
For the purpose of this article, we'll be comparing the following 2 lists to find common values that are present in both.
To compare two lists, here are the steps you need to follow:
Since our aim is to find matches, we select the first option and click Next.
A few different options are available here. For our purposes, these two are most useful:
For this example, I've decided to highlight duplicates in the following color:
And in a moment, got the following result:
With the Status column, the result would look as follows:
Tip. If the lists you are comparing are in different worksheets or workbooks, it might be helpful to view Excel sheets side by side.
This is how you compare columns in Excel for matches (duplicates) and differences (unique values). If you are interested to try this tool, you are welcome to download an evaluation version using the below link.
I thank you for reading and encourage you to check out other helpful tutorials that we have :)
Compare Excel Lists - examples (.xlsx file)
Ultimate Suite - trial version (.exe file)
Table of contents